اتصال ESP32 به بروکر MQTT با TLS (PubSubClient)

#include <WiFi.h>
#include <WiFiClientSecure.h>
#include <PubSubClient.h>

const char* WIFI_SSID = "your-wifi";
const char* WIFI_PASS = "your-wifi-password";

const char* MQTT_HOST = "mqtt.mqttcloud.ir";
const int   MQTT_PORT = 8883;
const char* MQTT_USER = "alice";          // your MQTT username
const char* MQTT_PASS = "YOUR_PASSWORD";
const char* CLIENT_ID = "esp32-01";       // registered in the dashboard

// ISRG Root X1, PEM from letsencrypt.org/certificates
const char* ROOT_CA = R"EOF(
-----BEGIN CERTIFICATE-----
...
-----END CERTIFICATE-----
)EOF";

WiFiClientSecure net;
PubSubClient client(net);

void onMessage(char* topic, byte* payload, unsigned int length) {
  Serial.printf("%s: %.*s\n", topic, length, (char*)payload);
}

void connectMqtt() {
  while (!client.connected()) {
    if (client.connect(CLIENT_ID, MQTT_USER, MQTT_PASS)) {
      client.subscribe("alice/esp32-01/cmd");
    } else {
      Serial.printf("MQTT connect failed, state=%d\n", client.state());
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  WiFi.begin(WIFI_SSID, WIFI_PASS);
  while (WiFi.status() != WL_CONNECTED) delay(500);

  net.setCACert(ROOT_CA);
  client.setServer(MQTT_HOST, MQTT_PORT);
  client.setCallback(onMessage);
  client.setBufferSize(512);  // default is 256 bytes
}

unsigned long lastSend = 0;

void loop() {
  if (!client.connected()) connectMqtt();
  client.loop();

  if (millis() - lastSend > 10000) {
    lastSend = millis();
    client.publish("alice/esp32-01/temp", "{\"c\":24.8}");
  }
}